Visual Basic Source Code/Visual Basic Source Code.iso/vbsource/alexrk/alexhelp.frm

Text File | 1995-09-06 | 6KB | 243 lines

VERSION 2.00
Begin Form Form2
   Caption         =   "Alex's Rocket Programmer Help"
   ClientHeight    =   4260
   ClientLeft      =   225
   ClientTop       =   2625
   ClientWidth     =   9240
   Height          =   4665
   Left            =   165
   LinkMode        =   1  'Source
   LinkTopic       =   "Form2"
   ScaleHeight     =   4260
   ScaleWidth      =   9240
   Top             =   2280
   Width           =   9360
   Begin TextBox HelpText
      Height          =   3345
      Left            =   3045
      MultiLine       =   -1  'True
      ScrollBars      =   2  'Vertical
      TabIndex        =   1
      Text            =   "HelpText"
      Top             =   600
      Width           =   6120
   End
   Begin ListBox HelpIndex
      Height          =   3150
      Left            =   30
      TabIndex        =   0
      Top             =   600
      Width           =   3030
   End
   Begin CommandButton Command2
      Caption         =   "Find Next"
      Height          =   360
      Left            =   4665
      TabIndex        =   3
      Top             =   135
      Width           =   1260
   End
   Begin CommandButton Command1
      Caption         =   "Exit Help"
      Height          =   360
      Left            =   3225
      TabIndex        =   2
      Top             =   135
      Width           =   1260
   End
   Begin Label Label1
      Caption         =   "Click Topic Below - Text will Appear in window at right"
      Height          =   480
      Left            =   120
      TabIndex        =   4
      Top             =   75
      Width           =   2955
   End
End
Dim HelpData As String
Dim IndexEntry As String
Dim NL As String
Dim StartSearch As Long

Sub CheckForContextLookup ()

    ' Help Topic can be loaded with a value to simulate
    '  context sensitive help
    If Len(HelpTopic$) > 0 Then
        StartSearch = 1
        LookupText (HelpTopic$)
    End If

End Sub

Sub Command1_Click ()

    Unload Form2

End Sub

Sub Command2_Click ()

    ' Find Next Control
    ' Execute same routine as normal lookup only don't reset
    ' starting point to top of text area
    StartSearch& = HelpText.selstart + 3

    ' return to top when end of file reached
    If StartSearch > Len(HelpText.Text) Then StartSearch = 1

    'FindString'
    HelpText.selstart = Len(HelpText.Text)

    LookupText (HelpTopic)

End Sub

Sub Form_GotFocus ()

Screen.MousePointer = 1

End Sub

Sub Form_Load ()

    Screen.MousePointer = 11

    StartSearch = 1

    LoadHelpIndex

    LoadHelpText

    CheckForContextLookup

End Sub

Sub HelpIndex_Click ()

    HelpTopic = LTrim$(RTrim$(HelpIndex.Text))

    LookupText (HelpTopic$)

End Sub

Sub HelpIndex_GotFocus ()

Screen.MousePointer = 1

End Sub

Sub HelpText_GotFocus ()

    Screen.MousePointer = 1

End Sub

Sub LoadHelpIndex ()

LoadIndexAgain:

On Error GoTo IndexError

' ** Help File data and index paths are stored in the first
' ** lines of the ALEX.BAS file
' ** Their default locations are C:\VB directory
' ** If they are not found there you will be prompted below to
' ** supply the correct path.

FN% = FreeFile
If NewHelpPath <> "" Then
    HelpIndexPath$ = RTrim$(LTrim$(NewHelpPath$)) + "\" + HelpIndexFile$
Else
    HelpIndexPath$ = HelpPath$ + "\" + HelpIndexFile$
End If

Open HelpIndexPath$ For Input As FN%

Do While Not EOF(FN%)
    Line Input #FN%, IndexEntry$
    HelpIndex.AddItem (IndexEntry$)
Loop

Close #FN%

Exit Sub

IndexError:
    NewHelpPath$ = RTrim$(InputBox$("Error Finding Help Files. Enter Drive and Directory where they are loaded. Default (assigned in .BAS file) is C:\VB.  Enter:", "Help Index Path", HelpPath))

    If NewHelpPath$ = "" Then Exit Sub

    ' Resume program execution with statement causing error
    Resume LoadIndexAgain

End Sub

Sub LoadHelpText ()

LoadTextAgain:

On Error GoTo TextError

' ** Help File data and index paths are stored in the first
' ** lines of the ALEX.BAS file
' ** Their default locations are C:\VB directory
' ** If they are not found there you will be prompted below to
' ** supply the correct path.

NL$ = Chr$(13) + Chr$(10)
FNT% = FreeFile
If NewHelpPath$ <> "" Then
    HelpTextPath$ = NewHelpPath$ + "\" + HelpTextFile$
Else
    HelpTextPath$ = HelpPath$ + "\" + HelpTextFile$
End If


Open HelpTextPath$ For Input As FNT%

Do While Not EOF(FNT%)
    Line Input #FNT%, HelpData$
    HelpTextLine$ = HelpTextLine$ + HelpData$ + NL$
    Loop

HelpText.Text = HelpTextLine$
Close #FNT%

Exit Sub

TextError:
    NewHelpPath = RTrim$(InputBox$("Error Finding Help Files. Enter Drive and Directory where they are loaded. Default (assigned in .BAS file) is C:\VB.  Enter:", "Help Text Path", HelpPath))

    If NewHelpPath$ = "" Then Exit Sub

    ' Resume program execution at satement causing error
    Resume LoadTextAgain

End Sub

Sub LookupText (HelpTopic As String)

    HelpText.selstart = Len(HelpText.Text)

'InStr returns location of text using the HelpTopic as lookup
' CSng convert this value for use in positioning
' within text box
    If InStr(StartSearch, HelpText.Text, HelpTopic) > 1 Then
        HelpText.selstart = InStr(StartSearch, HelpText.Text, HelpTopic) - 1
        HelpText.sellength = CSng(Len(HelpTopic))
    End If

    ' return to top when end of file reached
    If StartSearch > Len(HelpText.Text) Then StartSearch = 1

    ' Clear value of HelpTopic after each search unless
    ' FindNext drives the search
    ' HelpTopic = ""



End Sub